* Encoding: UTF-8.
*  SPSS syntax for the ANOVAs reported in Greaves et al. (in press) using the longitudinal NZAVS dataset.
*
*  Greaves, L. M., *Milojev, P., *Huang, Y., *Stronge, S., Osborne, D., Bulbulia, J., Grimshaw, M., & Sibley, C. G. (2015). 
*  Regional differences in the psychological recovery of Christchurch residents following the 2010/2011 earthquakes: 
*  a longitudinal study. PLoS ONE, 10, e0124278.
*
*  Syntax prepared by Petar Milojev and Lara Greaves
*
*------------Broader set of wards-----------


USE ALL.
COMPUTE filter_$=((WARD_2006.T01=05904) | (WARD_2006.T01=06001) | (WARD_2006.T01=06002) | 
    (WARD_2006.T01=06004) | (WARD_2006.T01=06005) | (WARD_2006.T01=06003) |(WARD_2006.T01=06006) | 
    (WARD_2006.T01=06202) | (WARD_2006.T01=06204) |(WARD_2006.T01=06007) | (WARD_2006.T01=05901)).
VARIABLE LABELS filter_$ '(WARD_2006.T01=05904) | (WARD_2006.T01=06001) | (WARD_2006.T01=06002) '+
    '| (WARD_2006.T01=06004) | (WARD_2006.T01=06005) | (WARD_2006.T01=06003) '+
    '|(WARD_2006.T01=06006) | (WARD_2006.T01=06202) | (WARD_2006.T01=06204) |(WARD_2006.T01=06007) '+
    '| (WA... (FILTER)'.
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.
FORMATS filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.

FREQUENCIES VARIABLES=WARD_2006.T01
  /ORDER=ANALYSIS.

*----------Specific wards of interest----------

USE ALL.
COMPUTE filter_$=((WARD_2006.T01=06001) | (WARD_2006.T01=06002) | (WARD_2006.T01=06004) | 
    (WARD_2006.T01=06005) | (WARD_2006.T01=06003) |(WARD_2006.T01=06006) ).
VARIABLE LABELS filter_$ '(WARD_2006.T01=06001) | (WARD_2006.T01=06002) | (WARD_2006.T01=06004) '+
    '| (WARD_2006.T01=06005) | (WARD_2006.T01=06003) |(WARD_2006.T01=06006)  (FILTER)'.
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.
FORMATS filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.

FREQUENCIES VARIABLES=WARD_2006.T01
  /ORDER=ANALYSIS.


*--------Computing combined wards of interest - damage-based regions-----------
*--------Most Damaged = Shirley/Burwood------
*--------Moderately Damaged = Hagley/Spreydon-----
*--------Least Damaged =  Fendalton/Riccarton-------

RECODE WARD_2006.T01 (6001=1) (6003=1) (6002=2) (6004=2) (6005=3) (6006=3) INTO ChChWards_3.
VARIABLE LABELS  ChChWards_3 'grouped wards'.
VALUE LABELS ChChWards_3 
1 'Shirley/Burwood'
2 'Fendalton/Riccarton'
3 'Hagley/Spreydon'.
EXECUTE.

FREQUENCIES VARIABLES=ChChWards_3
  /ORDER=ANALYSIS.

*--------Analysis of dropouts accross damage-based regions------------

CROSSTABS
  /TABLES= ChChWards_3 BY T02 T03 T04
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT ROW 
  /COUNT ROUND CELL.

*----------Computing Total Kessler6 scores--------

COMPUTE KESSLER6.T2 = T2.KESSLER6 * 6.
COMPUTE KESSLER6.T3 = T3.KESSLER6 * 6.
COMPUTE KESSLER6.T4 = T4.KESSLER6 * 6.

*---------General Linear Model assessing repeated K6 scores between wards, no covariates-----------
*---------Including the planned comparisons: ---
*---------#1 Fendalton/Riccarton vs. Hagley/Spreydon; #2Fendalton/Riccarton vs. Shirley/Burwood -----
*---------On the K6 at Time 4 ------

GLM KESSLER6.T2 KESSLER6.T3 KESSLER6.T4 BY ChChWards_3
  /WSFACTOR=Time 3 Polynomial 
  /METHOD=SSTYPE(3)
  /PLOT=PROFILE(Time*ChChWards_3)
  /PRINT=DESCRIPTIVE ETASQ 
  /CRITERIA=ALPHA(.05)
  /LMATRIX   =  ChChWards_3 0 -1 1
  /LMATRIX   =  ChChWards_3 1 -1 0
  /MMATRIX   = KESSLER6.T4 1
  /WSDESIGN=Time 
  /DESIGN=ChChWards_3.

*---------General Linear Model assessing repeated K6 scores between wards, adjusting for Gender and Age-----------
*---------Including the planned comparisons: ---
*---------#1 Fendalton/Riccarton vs. Hagley/Spreydon; #2Fendalton/Riccarton vs. Shirley/Burwood -----
*---------On the K6 at Time 4 ------

GLM KESSLER6.T2 KESSLER6.T3 KESSLER6.T4 BY ChChWards_3 WITH Gender.T2 Age.T2
  /WSFACTOR=Time 3 Polynomial 
  /METHOD=SSTYPE(3)
  /PLOT=PROFILE(Time*ChChWards_3) 
  /PRINT=DESCRIPTIVE ETASQ 
  /CRITERIA=ALPHA(.05)
  /LMATRIX   =  ChChWards_3 0 -1 1
  /LMATRIX   =  ChChWards_3 1 -1 0
  /MMATRIX   = KESSLER6.T4 1
  /WSDESIGN=Time 
  /DESIGN=Gender.T2 Age.T2 ChChWards_3.