TITLE:
      
  =================================================================================
  
    This script outlines the supplement to Milojev et al. estimating 
    the conditional probability of being in a specific class based on 
    specific values of the covariates. This is estimated using a 
    second-step analysis of the CPROB data output saved from the primary 
    analysis in the file titled Moral Signatures SAVEDATA.txt. 
         
    Milojev, P., Osborne, D., Greaves, L. M., Bulbulia, J., Wilson, M. S., 
    Davies, C. L., Liu, J. H., & Sibley, C. G. (2014). Right-Wing 
    Authoritarianism and Social Dominance Orientation predict different 
    moral signatures. Social Justice Research, 27, 149-174. 

    Syntax prepared by Petar Milojev

  =================================================================================
    
DATA:

FILE IS Moral Signatures SAVEDATA.txt;             

VARIABLE:   

IDVARIABLE IS subnum;
MISSING ARE ALL (9999);


NAMES ARE   
MFHAT35
MFFAT35
MFINT35
MFAUT35
MFPUT35
SUBNUM
GENT3
AGET3
NZDEPT3
ETHEURT3
RELIGT35
PARENTT3
PARTNRT3
EMPLOYT3
POLORIT3
SDOT3
RWAT3
ET3
AT3
CT3
NT3
OT3
HT3
CPROB1
CPROB2
CPROB3
CPROB4
C;

USEVARIABLE ARE
!GenT3 AgeT3
!NZDepT3 EthEurT3
!ReligT35
!ParentT3 PartnrT3
!EmployT3 PolOriT3
!SDOT3 RWAT3
!ET3 AT3 CT3 NT3 OT3 HT3
!CPROB1
!CPROB2
!CPROB3
CPROB4
!C
!Wprob1
!Logit;
Gen_C Age_C
NZDep_C  EthEur_C 
Relig_C 
Parent_C  Partnr_C 
Employ_C  PolOri_C 
SDO_C  RWA_C
E_C A_C C_C N_C O_C H_C;

DEFINE:
Gen_C = GenT3 - .369;
Age_C = AgeT3 - 50.040;
NZDep_C = NZDepT3 - 4.289;
EthEur_C = EthEurT3 - .770;
Relig_C = ReligT35 - .346;
Parent_C = ParentT3 - .708;
Partnr_C = PartnrT3 - .716;
Employ_C = EmployT3 - .782;
PolOri_C = PolOriT3 - 3.570;
SDO_C = SDOT3 - 2.356;
RWA_C = RWAT3 - 3.062;
E_C = ET3 - 3.924;
A_C = AT3 - 5.461;
C_C = CT3 - 4.975;
N_C = NT3 - 3.341;
O_C = OT3 - 5.098;
H_C = HT3 - 5.167;
!If (CPROB1 lt .00001) Then CPROB1 = .00001;
!If (CPROB1 gt .9999) Then CPROB1 = .9999;
!Logit = log(CPROB1/(1-CPROB1));
!Wprob1 = 1 - CPROB1;
ANALYSIS:
!COVERAGE = .33;
PROCESSORS = 4; 
ESTIMATOR = ML; 
MODEL:
CPROB4 ON Gen_C (a) 
          Age_C (b)
          NZDep_C (c) 
          EthEur_C (d)
          Relig_C (e)
          Parent_C (f)
          Partnr_C (g)
          Employ_C(h) 
          PolOri_C(i)
          SDO_C(j) 
          RWA_C(k)
          E_C(l) 
          A_C(m) 
          C_C(n) 
          N_C(o) 
          O_C(p) 
          H_C(q);

[CPROB4](z);

MODEL CONSTRAINTS:
NEW (msdo mrwa
     SDOLW SDOHI
     RWALW RWAHI
     sSDOLW sSDOHI
     sRWALW sRWAHI
     SDO1 SDO2
     RWA1 RWA2
     mE mA mC mN mO mH
     Elw Ehi Alw Ahi
     Clw Chi Nlw Nhi
     Olw Ohi Hlw Hhi
     E1 E2 A1 A2 C1 C2
     N1 N2 O1 O2 H1 H2
     sElw sEhi sAlw sAhi
     sClw sChi sNlw sNhi
     sOlw sOhi sHlw sHhi);

msdo = 2.356;
mrwa = 3.062;

SDOLW = 2.356 - .955;
SDOHI = 2.356 + .955;
RWALW = 3.062 - 1.144;
RWAHI = 3.062 + 1.144;

SDO1 = 0 - (msdo - SDOLW);
SDO2 = 0 - (msdo - SDOHI);

RWA1 = 0 - (mrwa - RWALW);
RWA2 = 0 - (mrwa - RWAHI);


sSDOLW = z + (j * SDO1);
sSDOHI = z + (j * SDO2);


sRWALW = z + (k * RWA1);
sRWAHI = z + (k * RWA2);

mE = 3.924;
mA = 5.461;
mC = 4.975;
mN = 3.341;
mO = 5.098;
mH = 5.167;

Elw = 3.924 - 1.192;
Ehi = 3.924 + 1.192;
Alw = 5.461 - .928;
Ahi = 5.461 + .928;
Clw = 4.975 - 1.023;
Chi = 4.975 + 1.023;
Nlw = 3.341 - 1.167;
Nhi = 3.341 + 1.167;
Olw = 5.098 - 1.095;
Ohi = 5.098 + 1.095;
Hlw = 5.167 - 1.191;
Hhi = 5.167 + 1.191;

E1 = 0 - (mE - Elw);
E2 = 0 - (mE - Ehi);
A1 = 0 - (mA - Alw);
A2 = 0 - (mA - Ahi);
C1 = 0 - (mC - Clw);
C2 = 0 - (mC - Chi);
N1 = 0 - (mN - Nlw);
N2 = 0 - (mN - Nhi);
O1 = 0 - (mO - Olw);
O2 = 0 - (mO - Ohi);
H1 = 0 - (mH - Hlw);
H2 = 0 - (mH - Hhi);

sElw = z + (l * E1);
sEhi = z + (l * E2);
sAlw = z + (m * A1);
sAhi = z + (m * A2);
sClw = z + (n * C1);
sChi = z + (n * C2);
sNlw = z + (o * N1);
sNhi = z + (o * N2);
sOlw = z + (p * O1);
sOhi = z + (p * O2);
sHlw = z + (q * H1);
sHhi = z + (q * H2);


OUTPUT: 
STDYX; SAMPSTAT;