TITLE:
      
  ======================================================================
  
    This script outlines the supplement to Cowie et al. estimating 
    the conditional probability of being in a specific class based on 
    specific values of the covariates. This is estimated using a 
    second-step analysis of the CPROB data output saved from the primary 
    analysis in the file titled Cowie DATA OUTPUT.txt. 

    Cowie, L. J., Greaves, L. M., & Sibley, C. G. (2015). Identifying 
    distinct subgroups of Green voters: a latent profile analysis of 
    crux values relating to Green Party support. New Zealand Journal 
    of Psychology, 44, 45-60.
    
    Updated 13-November-2019
  ======================================================================
    
DATA:

FILE IS Cowie DATA OUTPUT.txt;             

VARIABLE:   

IDVARIABLE IS subnum;
MISSING ARE ALL (9999);

NAMES ARE   
ENVVAL CLIMATE EQUL SOCJUS MAOPOLSU MAORIPOS WEALTH 
SUBNUM GENT4 AGET4 DEP13T4 ETHEURT4 ETHMAOT4 BORNNZT4 
RELIGT4 PARENTT4 PARTNRT4 EMPLOYT4 EDUT4 
CPROB1 CPROB2 CPROB3 CPROB4 C;

USEVARIABLE ARE
CPROB4 
GEN AGE DEP EUR MAO BORNNZ RELIG PARENT PARTNR EMPLOY EDU;

DEFINE:

GEN = GENT4 - 0.313;
AGE = AGET4 - 45.870;
DEP = DEP13T4 - 4.647;
EUR = ETHEURT4 - 0.943;
MAO = ETHMAOT4 - 0.123;
BORNNZ = BORNNZT4 - 0.800;
RELIG = RELIGT4 - 0.282;
PARENT = PARENTT4 - 0.637;
PARTNR = PARTNRT4 - 0.693;
EMPLOY = EMPLOYT4 - 0.782;
EDU = EDUT4 - 0.750;

ANALYSIS:
PROCESSORS = 4; ESTIMATOR = ML; 

MODEL:

CPROB4 ON GEN (a)
          AGE (b)
          DEP (c)
          EUR (d)
          MAO (e)
          BORNNZ (f)
          RELIG (g)
          PARENT (h)
          PARTNR (i)
          EMPLOY (j)
          EDU (k);

[CPROB4](z);

MODEL CONSTRAINT:

New (Men Wom Eur Eur_n Mao Mao_n Born Born_n Rel Rel_n 
     Parn Parn_n Part Part_n Empl Empl_n 
     pMen pWom pEur pEur_n pMao pMao_n pBorn pBorn_n pRel pRel_n 
     pParn pParn_n pPart pPart_n pEmpl pEmpl_n);

Men = 0 - (.315 - 1);
Wom = 0 - (.315 - 0);
Eur = 0 - (0.943 - 1);
Eur_n = 0 - (0.943 - 0);
Mao = 0 - (0.123 - 1);
Mao_n = 0 - (0.123 - 0);
Born = 0 - (0.800 - 1);
Born_n = 0 - (0.800 - 0);
Rel = 0 - (0.282 - 1);
Rel_n = 0 - (0.282 - 0);
Parn = 0 - (0.637 - 1);
Parn_n = 0 - (0.637 - 0);
Part = 0 - (0.693 - 1);
Part_n = 0 - (0.693 - 0);
Empl = 0 - (0.782 - 1);
Empl_n = 0 - (0.782 - 0);

pMen = z + (a * Men);
pWom = z + (a * Wom); 
pEur  = z + (d * Eur);
pEur_n  = z + (d * Eur_n);
pMao  = z + (e * Mao);
pMao_n  = z + (e * Mao_n);
pBorn  = z + (f * Born);
pBorn_n  = z + (f * Born_n);
pRel  = z + (g * Rel);
pRel_n  = z + (g * Rel_n);
pParn  = z + (h * Parn);
pParn_n  = z + (h * Parn_n);
pPart  = z + (i * Part);
pPart_n  = z + (i * Part_n);
pEmpl  = z + (j * Empl);
pEmpl_n  = z + (j * Empl_n);



OUTPUT: 

SAMPSTAT;