* Encoding: UTF-8.

* Lee, C. H. J., Duck, I. M., & Sibley, C. G. (in press). Confidence in the safety of standard childhood 
* vaccinations among health professionals in New Zealand. New Zealand Medical Journal. 


*Estimate means for different classes of health professional, with bootstrap CIs, treating vaccine attitudes
*as a continuous variable. 

BOOTSTRAP
  /SAMPLING METHOD=SIMPLE
  /VARIABLES TARGET=HLTH.ChildVaccination.T05 INPUT= Occupation.HealthCodes.T05 
  /CRITERIA CILEVEL=95 CITYPE=BCA  NSAMPLES=5000
  /MISSING USERMISSING=EXCLUDE.
MEANS TABLES=HLTH.ChildVaccination.T05 BY Occupation.HealthCodes.T05
  /CELLS=MEAN STDDEV COUNT SEMEAN
  /STATISTICS ANOVA.

*creates high/rest category of vaccine attitudes, following coding scheme proposed by Lee et al.

RECODE HLTH.ChildVaccination.T05 (1 thru 5=0) (6 thru 7=1) INTO VaccCat.
EXECUTE.

*cross tab of different classes of health professional who are high in vaccine support

CROSSTABS
  /TABLES=Occupation.HealthCodes.T05 BY VaccCat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT ROW 
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES=Occupation.HealthCodes.T05 BY HLTH.ChildVaccination.T05
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT 
  /COUNT ROUND CELL.

*ANOVA with bonferroni and games howell 

UNIANOVA HLTH.ChildVaccination.T05 BY Occupation.HealthCodes.T05
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /POSTHOC=Occupation.HealthCodes.T05(BONFERRONI GH) 
  /EMMEANS=TABLES(Occupation.HealthCodes.T05) 
  /PRINT=OPOWER ETASQ PARAMETER
  /CRITERIA=ALPHA(.05)
  /DESIGN=Occupation.HealthCodes.T05.


*ANCOVA with bonferroni post hoc

UNIANOVA HLTH.ChildVaccination.T05 BY Occupation.HealthCodes.T05 WITH Age.T05 Gender.T05 EthL2.Maori.T05 
    EthL2.Pacific.T05 EthL2.Asian.T05 Religious.T05 Parent.T05 Partner.T05 Urban.T05
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /EMMEANS=TABLES(Occupation.HealthCodes.T05) WITH(Age.T05=MEAN Gender.T05=MEAN EthL2.Maori.T05=MEAN 
    EthL2.Pacific.T05=MEAN EthL2.Asian.T05=MEAN Religious.T05=MEAN Parent.T05=MEAN Partner.T05=MEAN 
    Urban.T05=MEAN) COMPARE ADJ(BONFERRONI)
  /PRINT=OPOWER ETASQ HOMOGENEITY PARAMETER
  /CRITERIA=ALPHA(.05)
  /DESIGN=Age.T05 Gender.T05 EthL2.Maori.T05 EthL2.Pacific.T05 EthL2.Asian.T05 Religious.T05 Parent.T05 
    Partner.T05 Urban.T05 Occupation.HealthCodes.T05.

*demographics

CROSSTABS
  /TABLES=Occupation.HealthCodes.T05 BY Gender.T05 EthL2.Euro.T05 Religious.T05 Parent.T05 Urban.T05
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT 
  /COUNT ROUND CELL.

* demographics for full sample 

FREQUENCIES VARIABLES=Gender.T05 EthL2.Euro.T05 Urban.T05 Religious.T05
  /STATISTICS=STDDEV MEAN
  /ORDER=ANALYSIS.

DESCRIPTIVES VARIABLES=Age.T05 Personal.INC.T05
  /SAVE
  /STATISTICS=MEAN STDDEV MIN MAX.

*high vaccine support in adult NZ population overall (using sample weighting)

WEIGHT BY w.GendEthnicRegion.T05.

DESCRIPTIVES VARIABLES=HLTH.ChildVaccination.T05
  /STATISTICS=MEAN STDDEV MIN MAX.

FREQUENCIES VARIABLES=VaccCat HLTH.ChildVaccination.T05
  /ORDER=ANALYSIS.